Frequency Modulation Synthesis with FM-1

The FM-1 Class realizes a simple Frequency Modulation Synthesis with the following controls:

• The main amplitude,
• The frequency of the carrier, that is f0*n1,
• The frequency of the modulator, that is f0*n2,
• The amplitude envelope by means of a GEN routine,
• The index envelope by means of a GEN routine,
• The range between (imax & imin) of the index envelope.

The example A & B show the meaning of the FM index: the number of the components of the side-band frequencies increase with the rising of the index.

The example C focuses on the carrier multiplication factor (n1) with a steady sideband width (100*0.1=10 Hz). The sound begins rough and ends with a nice vibrato for the sake of the ratio between the modulating and the carrier frequency. At the beginning the sidebands are 10% away from the carrier i.e., M/C = ((f0*n2)/(f0*n1)) = n2/n1 = 0.1/1 = 0.1. At the end they are 0.625% away (0.1/16).

The example D focuses on the ratio between the modulating and the carrier frequency.

• M/C > 0.1 -> vibrato,
• M/C = integer or 1/2^n -> harmonic spectra,
• M/C = floating -> inharmonic spectra

instr 1

idur = p3

idurosc = 1/idur

iamp = (p4 > 0.0 ? (p4*0.001*0dbfs) : (ampdbfs (p4)))

if0 = p5

in1 = p6

in2 = p7

icar = if0*in1

imod = if0*in2

imax = p8

imin = p9

imindev = imin*imod

imaxdev = imax*imod

ivardev = imaxdev-imindev

iaenv = p10

ienv = p11

icarfun = 1

imodfun = 2

ieps = 0.01

ken poscil iamp, idurosc, iaenv

k1 linseg 1, idur-ieps, 1, ieps, 0 ; avoid clicks

kenv = ken * k1

ki poscil ivardev, idurosc, ienv

kind = imindev + ki

amod poscil kind, imod, imodfun

asound poscil kenv, icar+amod, icarfun ; carrier

out asound

endin