Reading from a Sound file with SMPL-A1

The Smpl-A1 Class is a Sampler with the following controls:

• The main ampllitude,
• The transposition range,
• The transposition envelope by means of a GEN routine,
• The frequency of the transposition envelope,
• The range and amplitude of the jitter of the frequency,
• The starting point of the audio file,
• The amplitude envelope by means of a GEN routine,
• The attack and decay time of the total duration of the amplitude envelope,
• The wrapping mode (enable or disable)

The example A displays many transposition's ranges.

The example B collects four different transposition's envelopes.

The example C considers closely the frequency of the transposition's envelope. The default value is 0 and take the global duration, the other values express the cycle per second of the envelope.

The example D deals with the frequency's jitter, which is equal to the pitch transposition multiplied by the given data (f0*f0jta).

The example E shows the effects of the amplitude of the jitter.

instr 1

idur = p3

idurosc = 1/idur

iamp = (p4 > 0.0 ? (p4*0.001) : (10 ^ (p4/20.0)))

; amplitude relative to the sound file (to avoid multiplying twice)

if0min = p5 ; min transposition factor

if0max = p6

if0d = if0max-if0min

if0env = p7

if0jt = p8

if0dur = (p9 > 0 ? p9 : idur)

ijta = p10

ifile = p11

iskip = (p12 < 0.0 ? (p12*if0min) : p12)

; to make the value not depend on the xposition factor if it's negative

iskip = p12

iaenv = p13 ; global amplitude envelope

iwin = (p14 > idur/2 ? idur/2 : p14) ; local envelope

iwout = iwin

iwrap = p15

print iskip

ixmode = 1 ; index between 0 and 1

ixoff = 0 ; index offset

ixrap = 0 ; no wraparound in table reading

iformat = 8 ; 24-bit int, ignored if the sound file has a header

iwsize = 512 ; the bigger, the better the quality of the transposition

ibufsize = 262144 ; maximum = 1048576, higher makes less disk access

iskipinit = 0 ; do not skip initialization

isize = 1 ; 31-bit random number for randi

iaudiofun = 1

isigfun = 19 ; sigmoid function

;f0

; jitter for f0

; seed>1.0=> seed from the system time

kf0j1 randi if0jt, 1/0.05, 1.8135, isize

kf0j2 randi if0jt, 1/0.111, 1.3111, isize

kf0j3 randi if0jt, 1/1.219, 1.6711, isize

kf0j = (kf0j1+kf0j2+kf0j3)/3.0

;f0 envelope

kf0env poscil if0d, 1/if0dur, if0env

kf0 = kf0env+if0min

kf0end = kf0+(kf0*kf0j)

; local envelope (for the grain)

k1 linen 1,iwin,idur,iwout

k2 tablei k1,isigfun,ixmode,ixoff,ixrap

; jitter for amp

; seed>1.0=> seed from the system time

kjta1 randi ijta, 1/0.061, 1.8195, isize

kjta2 randi ijta, 1/0.109, 1.3011, isize

kjta3 randi ijta, 1/1.221, 1.6793, isize

kjta = (kjta1+kjta2+kjta3)/3.0

; global envelope

k3 poscil iamp, idurosc, iaenv

kamp = k3+(k3*kjta)

; file reading

a1 diskin2 ifile, kf0end, iskip, iwrap, iformat, iwsize, ibufsize, iskipinit

asound = a1*k2*kamp

outc asound

endin